[kuek_2000]

Hay un post de Marzo del 2007 donde se publicaron la formulas para el desarrollo plano de un cono truncado, lo cual me valio para mi trabajo, pero os pido ayuda para saber como se hace el desarrollo de un codo genérico.

Gracias por vuestra ayuda

[Jonno]

Si nos enseñas una imagen de eso que llamas "codo genérico" igual te podemos ayudar. Yo al menos no sé lo que es, pero si lo veo igual sé cómo se hace el desarrollo.

[kuek_2000]

No se meter imagenes en este post ya que me pide una url. Cuando me refiero a un codo generérico, es un tubo de 90º sin unas medidas en concreto. Yo lo necesito para hacerlo de acero desde un chapa. Se que en los conductos de ventilación, estos codos los hacen por medio de varios tramos, luego los unen y forman el codo, pero tampoco se como se hace su desarrollo. Me valdrían cualquier solución para poder fabricar dicho codo. En cuanto a una imagen, yo encantado por publicarla pero me sale una ventana pidiendome la url, entonces estoy perdido.

Gracias a todos por vuestra atención y tiempo, a ver si se puede dar una solución a esto.

[kuek_2000]

Un codo generico es un tubo en 90 grados sin unas medidas en concreto, es decir, un radio r, un diametro D,...se q en los conductos de ventilacion, este codo, lo hacen en varios tramos y luego lo unen, pero yo lo tebngo q hacer desde una chapa de acero y curvarlo para tener el codo, por eso necesito hacer el desarrollo plano, para meterlo en una chapa y cortar. En cuanto meter una imagen, yo encantado pero al darle a insertar una imagen me sale una ventana pidiendome una url, y estoy perdido, si me lo explicais yo encantado.

Gracias por vuestro tiempo y haber si me podeis hechar una mano.

[neomac]

kuek … tienes que poner primero la imagen en algun servidor y luego desde aquí enlazarla … si usas las búsquedas hay por ahi un manual para colgar imágenes …

Aunque mas o menos lo visualizo es difícil enterder lo que quieres … y el tema de la chapa a mi personalmente me despista mucho … cuelga la imagen y explícalo más en concreto …

Saludos,

[kuek_2000]

Esta imagen responde a lo q me refiero a un codo generico, ¿como se hace el desarrollo plano? Yo no tengo ni p**a idea

[Jonno]

Es que eso no puedes hacerlo en plano.

Como mucho podrías hacer una aproximación, y además no tiene pinta de ser fácil.

[ferreirolo]

Hola:

kuek_2000, en Feb 2 2008, 03:17 PM, dijo:

Esta imagen responde a lo q me refiero a un codo generico, ¿como se hace el desarrollo plano? Yo no tengo ni p**a idea

Con Autocad, haz una búsqueda en Google por: desarrollo codo calderería Filetype:pdf y verás varios ejemplos como este.

Saludos.

[estifMACuín]

ferreirolo, en Feb 3 2008, 10:16 AM, dijo:

Con Autocad, haz una búsqueda en Google por: desarrollo codo calderería Filetype:pdf y verás varios ejemplos como este.
Saludos.

parece que kuek necesita el desarrollo de un codo de una sola pieza, no uno compuesto por una sucesión de troncos de cono o de cilindros.

Con matemáticas "normales" en la mano, no se puede. Si el codo lo materializas con chapa plegada (ondulada), el desarrollo es un rectángulo de lado mayor el eje del codo. Te puede quedar mejor ajustando la parte ondulada para que la cara externa te quede lisa (y pliegues sólo en la interna, o la del vértice). Vamos, lo que viene a ser la pajita de los refrescos.

un saludo.

[kuek_2000]

Lo primero de todo gracias por vuestras respuestas me han resultado de gran ayuda. Entiendo que paera hacer el codo de una sola pieza hay q hacerlo desde algún programa especializado de calderería utilizando el AutoCad, con lo cual esa parte la tendre resuelta (tendré q decir en mi empresa q hay q comprar un programilla de despieces), pero solo me queda una duda, como podría hacer el codo si tubiera la posibildad de poder hacerlo en varios gajos, dos, tres o los q sean necesarios. Es q trata de una obra muy concreta donde no creo q tenga inconvenientes en fabricar este codo en varios gajos y me temo mucho q no me van a poder permitir comprar el programa de autocad.

Gracias por vuestro tiempo. Un saludo

[Jonno]

Como el tema se sale del campo de las artes gráficas lo paso al foro de 3D

[diprolam]

Se tienen que hacer una serie de trazos en una superficie, por ejemplo lámina, para poder
realizar el desarrollo.

Esto se usa en el aire acondicionado para fabricar codos de lámina ó cuando forran las tuberías
de calor industrial, etc.

El resultado que vas a obtener va a ser un codo segmentado en gajos. No precisamente un
codo liso. Si aumentas el número de gajos aumentara la exactitud.

Si sabes utilizar Autolisp en Autocad esta rutina traza los desarrollos de forma automática.
Espero te sirva.



;; Nombre : codo.lsp
;; Descripcion : Programa para trazar el desarrollo de un codo en gajos
;;
;; Revisiones :
;; 2/Ago/95 Correccion de errores criticos.
;; 11/Oct/95 Se agrego trazo de gajo 1
;; 6/Mzo/96 Se agrego trazo de gajo 2

;;==============================================
;; Rutina para convertir grados a radianes
;;==============================================
(defun DTR(angulo) (* pi (/ angulo 180.0) ) )

;;==============================================
;; Programa principal
;;==============================================
(defun c:gajo()
(setvar "CMDECHO" 0)
(setvar "OSMODE" 0)

(if (= dn nil) (setq dn 0.0) )
(if (= subd nil) (setq subd 16.0) )
(setq di dn)
(setq dn (getreal (strcat "\nCual es el diametro ? < " (rtos di) " >") ) )

(if (= dn nil) (setq dn di) )

(while (= dn 0.0) (setq dn (getreal "\nDiametro del codo? ( 0 NO VALIDO ) " ) ) )

(if (or (= rc nil) (< rc (* 1.5 dn) ) ) (setq rc (* 1.5 dn) ) )

(setq rcan rc
rc (getreal (strcat "\nRadio del codo ? < " (rtos rc) " >") )
)

(if (= rc nil) (setq rc rcan) )

(while (< rc (/ dn 2.0) )
(setq rc (getreal "\nRadio del codo ? ( es VALIDO >= a el Radio ) " ) )
)

(if (or (= g nil) (= g 0) ) (setq g 4) )

(setq gan g
g (getint (strcat "\nNo. de gajos ? < " (itoa g) " >") )
)

(if (= ac nil) (setq ac 90.0) )

(setq aca ac)

(if (= g nil) (setq g gan) )

(while (< g 2.0)
(setq g (getint "\nNumero de Gajos ? ( mas de 1 es VALIDO ) " ) )
)

(setq ac (getreal (strcat "\nAngulo del codo ? < " (rtos ac) " >") ) )

(if (= ac nil) (setq ac aca) )

(while (or (< ac 10.0) (> ac 180.0) )
(setq ac (getreal "\nAngulo de codo ? ( 10 <= ang. VALIDO <= 180 ) " ) )
)

(setq pt1 (getpoint "\nPunto de Inicio ? ")
ag (/ ac g)
h1 (/ (* (- rc (/ dn 2.0) ) (sin (/ (DTR ag) 2.0) ) ) (cos (/ (DTR ag) 2.0) ) )
h2 (/ (* (+ rc (/ dn 2.0) ) (sin (/ (DTR ag) 2.0) ) ) (cos (/ (DTR ag) 2.0) ) )
h3 (/ (* pi dn) subd)
)

(setq pt2 (polar pt1 0.0 (- rc (/ dn 2.0) ) )
pt3 (polar pt1 0.0 (+ rc (/ dn 2.0) ) )
pt4 (polar pt2 (DTR 90.0) h1)
pt5 (polar pt3 (DTR 90.0) h2)
pt6 (polar pt1 0.0 rc)
pt7 (polar pt6 (DTR 270.0) dn)
av ag
cont 1
)

;;==============================================
;;Trazo de Elevacion
;;==============================================
(command "_line" pt4 pt2 ""
"_line" pt2 pt3 ""
"_line" pt3 pt5 ""
"_CIRCLE" pt7 (polar pt7 (DTR 90.0) (/ dn 2.0) )
)

(while (< cont g)
(command "_line" pt4 pt5 "")

(setq pt6 (polar pt1 (DTR av) (- rc (/ dn 2.0) ) )
pt7 (polar pt1 (DTR av) (+ rc (/ dn 2.0) ) )
)

(command "_line" pt4 (polar pt6 (DTR (+ 90.0 av) ) h1) ""
"_line" pt5 (polar pt7 (DTR (+ 90.0 av) ) h2) ""
)

(setq pt4 (polar pt6 (DTR (+ 90.0 av) ) h1)
pt5 (polar pt7 (DTR (+ 90.0 av) ) h2)
av (+ av ag)
cont (+ cont 1)
)
);;fin while

(command "_line" pt4 pt5 "")

(setq pt6 (polar pt1 (DTR ac) (- rc (/ dn 2.0) ) )
pt7 (polar pt1 (DTR ac) (+ rc (/ dn 2.0) ) )
)

(command "_line" pt4 pt6 pt7 pt5 "")

;;==============================================
;;Trazo plantilla 1/2 gajo
;;==============================================
(setq pt4 (polar pt1 0.0 (+ rc (* 1.5 dn) ) )
pt1a (polar pt1 0.0 (+ rc (* 1.5 dn) ) )
pt1b (polar pt1a (DTR 90.0) (* 3.0 h2) )
pt1c (polar pt1a (DTR 90.0) (* 6.0 h2) )
pt5 (polar pt4 (DTR 90.0) h1)
cont 1
)

(command "_line" pt4 pt5 "")

(while (<= cont subd)
(setq pt6 (polar pt4 0.0 h3)
hv (/ (* (- rc
(* (/ dn 2.0)
(cos (DTR (* cont (/ 360.0 subd) ) ) )
)
)
(sin (/ (DTR ag) 2.0) )
)
(cos (/ (DTR ag) 2.0) )
)
pt7 (polar pt6 (DTR 90.0) hv)
)

(command "_line" pt4 pt6 pt7 pt5 "")

(setq pt4 pt6
pt5 pt7
cont (+ cont 1)
)
);;fin while

;;==============================================
;;Trazo plantilla gajo 1
;;==============================================
(setq pt4 (polar pt1b (DTR 270.0) h2)
pt5 (polar pt1b (DTR 90.0) h2)
cont 1
)

(command "_line" pt4 pt5 "")

(while (<= cont subd)
(setq pt1b (polar pt1b 0.0 h3)
hv (/ (* (+ rc
(* (/ dn 2.0)
(cos (DTR (* cont (/ 360.0 subd) ) ) )
)
)
(sin (/ (DTR ag) 2.0) )
)
(cos (/ (DTR ag) 2.0) )
)
pt7 (polar pt1b (DTR 90.0) hv)
pt6 (polar pt1b (DTR 270.0) hv)
)

(command "_line" pt4 pt6 pt7 pt5 "")

(setq pt4 pt6
pt5 pt7
cont (+ cont 1)
)
);;fin while

;;==============================================
;;Trazo plantilla gajo 2
;;==============================================
(setq pt4 (polar pt1c (DTR 270.0) h1)
pt5 (polar pt1c (DTR 90.0) h1)
cont 1
)

(command "_line" pt4 pt5 "")

(while (<= cont subd)
(setq pt1c (polar pt1c 0.0 h3)
hv (/ (* (- rc
(* (/ dn 2.0)
(cos (DTR (* cont (/ 360.0 subd) ) ) )
)
)
(sin (/ (DTR ag) 2.0) )
)
(cos (/ (DTR ag) 2.0) )
)
pt7 (polar pt1c (DTR 90.0) hv)
pt6 (polar pt1c (DTR 270.0) hv)
)

(command "_line" pt4 pt6 pt7 pt5 "")

(setq pt4 pt6
pt5 pt7
cont (+ cont 1)
)
);;fin while
)